Re: tables html dsssl HELP!

["G. Ken Holman" <gkholman@xxxxxxxxxxxxxx>]

Hi Daniel,

At 14:49 97/10/13 -0400, Daniel Pitti wrote:
>I would like to add spacing
>between each row -- there are no borders. How would I do this using your
>example below?

First, to turn off the border there is no need to have the
cell-before-????-border characteristics, so in this example I left out the
row border and left in the column border.

Next, I added spacing by flowing a paragraph flow object into the cell,
rather than just text of the child of the element.  This allows me to use
the space-before characteristic to adjust vertical spacing.

If I understand your requirement correctly, the following "samp3.dsl"
should do the trick.

Good luck ............. Ken

p.s. In the event you wanted just spacing between cell contents and not
before the first row's cell contents, I created "samp3b.dsl" which doesn't
space before the first row.

F:\FTEMP>type samp3.sgm
<!DOCTYPE t [
<!ELEMENT t - O ( r+ )      -- table  -->
<!ELEMENT r - O ( c+ )      -- row    -->
<!ELEMENT c - O ( #PCDATA ) -- column -->
]><t>
<r><c>r1c1<c>r1c2
<r><c>r2c1<c>r2c2

F:\FTEMP>type samp3.dsl
<!DOCTYPE style-sheet PUBLIC "-//James Clark//DTD DSSSL Style Sheet//EN">

(element t                      ;the processing of the table element
    (make table
        table-border:  (make table-border line-thickness: 3pt)
        (make table-column width: 1in)  ;all columns before any rows
        (make table-column width: 2in)
        (process-children)))            ;child elements make row flow objs

(element r                      ;a row in the table
    (make table-row
        (process-children)))    ;child elements make cell flow objects

(element c                      ;a column in the row
    (make table-cell
        cell-before-column-border: #t
        (make paragraph
            space-before: 2cm
            (process-children))))   ;content of the table cell

; end of file


F:\FTEMP>jade -c %jadedir%catalog -t rtf -d samp3.dsl samp3.sgm

F:\FTEMP>type samp3b.dsl
<!DOCTYPE style-sheet PUBLIC "-//James Clark//DTD DSSSL Style Sheet//EN">

(element t                      ;the processing of the table element
    (make table
        table-border:  (make table-border line-thickness: 3pt)
        (make table-column width: 1in)  ;all columns before any rows
        (make table-column width: 2in)
        (process-children)))            ;child elements make row flow objs

(element r                      ;a row in the table
    (make table-row
        (process-children)))    ;child elements make cell flow objects

(element c                      ;a column in the row
    (make table-cell            ;content of the table cell
        cell-before-column-border: #t
        (make paragraph     ;with extra room
            space-before:   (if (equal? (child-number
                                            (parent (current-node)))
                                        1)
                                0cm
                                2cm)
            (process-children))))

; end of file


F:\FTEMP>jade -c %jadedir%catalog -t rtf -d samp3b.dsl samp3.sgm

F:\FTEMP>


--
G. Ken Holman            mailto:gkholman@xxxxxxxxxxxxxx
Crane Softwrights Ltd.  http://www.CraneSoftwrights.com
1605 Mardick Court, Box 266,         V: +1(613)489-0999
Kars, Ontario CANADA K0A-2E0         F: +1(613)489-0995
PGP Privacy: http://www.cyberus.ca/~holman/gkholman.pgp
Training:  http://www.CraneSoftwrights.com/schedule.htm

 DSSSList info and archive:  http://www.mulberrytech.com/dsssl/dssslist