RE: [xsl] passing intermediate result while recursively building nodeset

["Michael Kay" <michael.h.kay@xxxxxxxxxxxx>]

> I have question which is a variation of a previous question I
> had ... I'd like to recursively build up a nodeset, and I'd
> like to pass the intermediate result on with each recursive call.
>
> For example, if the template is passed the nodeset:
>     <a i=1/><a i=2/>
> and it creates the node:
>     <a i=3/>
> then I'd like to the template to recursively call itself
> passing the nodeset:
>     <a i=1/><a i=2/><a i=3/>
>
> Is this possible/reasonable/efficient?
>
As others have indicated, it's possible, but it's not necessarily going to
be efficient. Doing a recursive template like

<xsl:template name="build">
  <xsl:param name="n"/>
  <xsl:param name="tree"/>
  <xsl:call-template name="build">
     <xsl:with-param name="n" select="$n+1"/>
     <xsl:with-param name="tree">
       <xsl:copy-of select="$tree"/>
       <a i="{$n}"/>
     </xsl:with-param>
  </xsl:call-template>
</xsl:template>

will work (if you give it a terminating condition), but it will have O(n^2)
performance.

However, the nodes in a node-set don't have to be in the same tree. You can
equally well create a node-set by putting each new node in a different tree:

<xsl:template name="build">
  <xsl:param name="n"/>
  <xsl:param name="nodeset"/>
  <xsl:variable name="new">
    <a i="{$n}"/>
  </xsl:variable>
  <xsl:call-template name="build">
     <xsl:with-param name="n" select="$n+1"/>
     <xsl:with-param name="nodeset" select="$new/a | $nodeset"/>
  </xsl:call-template>
</xsl:template>

This will probably be faster than building the tree incrementally, but it
has two drawbacks: (a) it requires the xx:node-set() extension in XSLT 1.0,
and (b) there is no guarantee about the order of the nodes from different
documents.

So the question is, what are you actually trying to achieve?

Michael Kay
Software AG
home: Michael.H.Kay@xxxxxxxxxxxx
work: Michael.Kay@xxxxxxxxxxxxxx


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list