Re: [xsl] not()'ing a false variable, xalan 2.4.D1

["G. Ken Holman" <gkholman@xxxxxxxxxxxxxxxxxxxx>]

At 2002-11-07 19:25 -0600, Elizabeth Barham wrote:
> The reason I am trying to do this is because I have created a template
> that tests for a certain condition and returns true or false, for
> example:

To do it the way you are asking, you can use any string value for true and 
the empty string for false ... then, just have your template create text 
when you want true and not create text when you want false.

The principle is that string() on a result tree fragment concatenates all 
the text nodes ... if there are no text nodes, the string is empty, and 
this tests to false.

A working example is below.

I hope this helps.

.............. Ken


T:\ftemp>type elizabeth.xml
<?xml version="1.0" encoding="iso-8859-1"?>
<doc>
  <test>
    <name>First</name>
    <x/>
  </test>
  <test>
    <name>Second</name>
    <y/>
  </test>
  <test>
    <name>Third</name>
  </test>
</doc>
T:\ftemp>type elizabeth.xsl
<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
                version="1.0">

<xsl:output method="text"/>

<xsl:template name="boolean-function-template">
  <xsl:param name="node-set"/>
  <xsl:choose>
    <xsl:when test="$node-set/x"/>
    <xsl:when test="$node-set/y">HELLO!</xsl:when> <!--or any string-->
  </xsl:choose>
</xsl:template>

<xsl:template match="/">
  <xsl:for-each select="doc/test">
    <xsl:variable name="variable">
      <xsl:call-template name="boolean-function-template">
        <xsl:with-param name="node-set" select="."/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:value-of select="name"/>: <xsl:text/>
    <xsl:if test="string($variable)">
      <xsl:text>True!!</xsl:text>
    </xsl:if>
    <xsl:text>
</xsl:text>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

T:\ftemp>xt elizabeth.xml elizabeth.xsl
First:
Second: True!!
Third:

T:\ftemp>rem Done!


--
Upcoming hands-on in-depth XSLT/XPath and/or XSL-FO:
-                             North America:  Feb 3 - Feb 7,2003

G. Ken Holman               mailto:gkholman@xxxxxxxxxxxxxxxxxxxx
Crane Softwrights Ltd.        http://www.CraneSoftwrights.com/s/
Box 266, Kars, Ontario CANADA K0A-2E0  +1(613)489-0999 (F:-0995)
ISBN 0-13-065196-6                     Definitive XSLT and XPath
ISBN 0-13-140374-5                             Definitive XSL-FO
ISBN 1-894049-08-X Practical Transformation Using XSLT and XPath
ISBN 1-894049-10-1             Practical Formatting Using XSL-FO
Next conference training:                    2002-12-08,03-03,06


XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list