Re: [xsl] Nested loops

Subject: Re: [xsl] Nested loops
From: Peter Bradley <apvx95@xxxxxxxxxxxxx>
Date: Sat, 13 Nov 2004 12:54:52 +0000
Ysgrifennodd G. Ken Holman:
At 2004-11-13 11:53 +0000, Peter Bradley wrote:

<snip />

So I need some sort of nested loop.


Yes, nested "for-each" loops would do the trick simply if you don't have to deal with duplicates and determine only the unique ones from those.

Now, I take the point I learnt last week that this is probably best done using <xsl:apply-templates>,


Sure, that works too, a writer's choice of pull or push depends on how granular you want your stylesheet for later specialization, or how you want to use the template rules for other contexts.

but how can I just pick the node set that has the correct invoice number? That is, I need to do something like:

* apply the invoice_rec template


Process "/database/invoice/invoice_rec"

Yup. Got that.



* print the contents
* apply the invoice_line_rec template for nodes sharing an invoiceNumber with the invoice_rec it's "called" from


   Process "../../invoice_line/
                  invoice_line_rec[invoiceNumber=current()/invoiceNumber]"


That's where I'm screwing up!


* apply the invoice_total template for the node sharing the invoice number


   Process "../../invoice_line/
                  invoice_total[invoiceNumber=current()/invoiceNumber]:

Do this for each invoice_rec.


Either pull:

   <xsl:for-each select="/database/invoice/invoice_rec">
      ...print the contents...
      <xsl:for-each select="../../invoice_line/
                  invoice_line_rec[invoiceNumber=current()/invoiceNumber]">
        ...print the line...
      </xsl:for-each>
      <xsl:for-each select="../../invoice_line/
                  invoice_total[invoiceNumber=current()/invoiceNumber]">
        ...print total...
      </xsl:for-each>
   </xsl:for_each>

Or push:

<xsl:template match="/">
<xsl:apply-templates select="/database/invoice/invoice_rec"/>
</xsl:template>
<xsl:template match="invoice_rec">
...print the contents...
<xsl:apply-templates select="../../invoice_line/
invoice_line_rec[invoiceNumber=current()/invoiceNumber]"/>
<xsl:apply-templates select="../../invoice_line/
invoice_total[invoiceNumber=current()/invoiceNumber]"/>
</xsl:template>
<xsl:template match="invoice_line_rec">
...print the line...
</xsl:template>
<xsl:template match="invoice_total">
...print the total...
</xsl:template>


I've tried all sorts of things including predicates and variables, but I just can't seen to find a valid XPath expression that gives me the node set I need.


When you walk away from the current node in the evaluation of an XPath expression, the current() function can be used to "jump back" to where you started from the middle of the expression.

The above assumes you aren't having to deal with duplicates.

Put your focus on each invoice record and then address relatively from that record to all of the lines and the total whose reference is equal to the record you ware dealing with.

You can also do it with keys:

   <xsl:key name="recs" match="invoice_rec" use="'all'"/>
   <xsl:key name="lines" match="invoice_line" use="invoiceNumber"/>
   <xsl:key name="totals" match="invoice_total" use="invoiceNumber"/>

   <xsl:template match="/">
     <xsl:for-each select="key(recs,'all')">
       ...do contents...
       <xsl:for-each select="key(lines,invoiceNumber)">
         ...do line...
       </xsl:for-each>
       <xsl:for-each select="key(totals,invoiceNumber)">
         ...do total...
       </xsl:for-each>
     </xsl:for-each>
   </xsl:template>

I hope this helps. It is untested since you didn't give any data to play with.

No, I didn't. I want to make at least some input for myself, or I'd feel like a cheat when I put in my submission - even with attributions.


But if you'd like some data, I'll post a url later on. After I've had a chance to play by myself for a while.


............................ Ken



Thanks to both you and Bruce. I'm off to try to apply this stuff now. I'll post again to let you know how I got on.


Cheers


Peter


Current Thread