Re: [xsl] How to split an RegEx into several lines for readability?

Subject: Re: [xsl] How to split an RegEx into several lines for readability?
From: David Carlisle <davidc@xxxxxxxxx>
Date: Sun, 29 Apr 2007 21:42:27 +0100
Colin has mentioned the x flag (which allows you to add ignored white
space, also, since you are using xsl:analyze-string, the regex is an
attribute value template so you can define the regexp parts separately
and drop them in using {}.

For example this monster regex that matches tags in hmlparse


     regex="&lt;(/?){$d:elem}\s*(({$d:attr})*)(/?)>|{$d:comment}|{$d:pi}|{$d:doctype}|{$d:cdata}|({$d:msif})">

the regex that match each type of markup are in separate variables for
readability, they are only used once, in this expression.

<xsl:variable name="d:attr"
   select="'(\i\c*)\s*(=\s*(&quot;[^&quot;]*&quot;|''[^'']*''|\c+))?\s*'"/>

<xsl:variable name="d:elem"
   select="'(\i\c*)'"/>

<xsl:variable name="d:comment"
   select="'&lt;!\-\-[^\-]*(\-[^\-]+)*\-\->'"/>

<xsl:variable name="d:pi"
   select="'&lt;\?\i\c*[^>]*>'"/>

<xsl:variable name="d:doctype"
   select="'&lt;!D[^\[&lt;>]*(\[[^\]]*\])?>'"/>


<xsl:variable name="d:msif"
   select="'&lt;!\[(end)?if.*?\]>'"/>

<xsl:variable name="d:cdata"
   select="'&lt;!\[CDATA(.|\s)*\]\]>'"/>



David

________________________________________________________________________
The Numerical Algorithms Group Ltd is a company registered in England and Wales with company number 1249803. The registered office is:
Wilkinson House, Jordan Hill Road, Oxford OX2 8DR, United Kingdom.

This e-mail has been scanned for all viruses by Star. The service is powered by MessageLabs. ________________________________________________________________________

Current Thread