Re: [xsl] Function to accept node and name of subnode in parameter string

Subject: Re: [xsl] Function to accept node and name of subnode in parameter string
From: "G. Ken Holman" <gkholman@xxxxxxxxxxxxxxxxxxxx>
Date: Wed, 20 Aug 2008 15:40:28 -0400
At 2008-08-20 14:29 -0500, Bordeman, Chris wrote:
Hi all.  I need to create a 2.0 function that will accept an element()?
and a xs:string.  The string will contain the name of a subnode of the
first parameter.

The function will do something like this:

<!-- Given any node and the name of a subnode, returns
     the nonempty subnode's value or N/A -->
<xsl:function name="fn:ValueOrNA" as="xs:string">
        <xsl:param name="node" as="element()?"/>
        <xsl:param name="childelementname" as="xs:string"/>
        <xsl:choose>
                <xsl:when test="$node and $node/$childname != ''">
                        <xsl:value-of select="$node/$childname"/>
                </xsl:when>
                <xsl:otherwise>
                        <xsl:value-of select="'N/A'"/>
                </xsl:otherwise>
        </xsl:choose>
</xsl:function>

But it always seems to return just the second string I pass in, not the
value of the subnode.

Yes, because in XSLT 2.0 any step in a location path is allowed to be a primary expression of which a string literal is one.


What's the right way to do this?

By making some assumptions on namespace prefixes and finding the node you are looking for.


  <xsl:when test="$node and $node/*[name(.)=$childname] != ''">
    <xsl:value-of select="$node/*[name(.)=$childname]"/>
  </xsl:when>

... but the above assumes that your $childname contains the same prefix-qualified name as your input tree. If you only want to check on the name portion without the prefix, then you will need local-name(.) instead of name(.).

If you need a complete namespace-safe solution then pass in a third argument:

<xsl:param name="childns" as="xs:string"/>

... and the following test will work indpendent of any prefix chosen by the author of the document:

  <xsl:when test="$node and $node/*[local-name(.)=$childname and
                                    namespace-uri(.)=$childns] != ''">
    <xsl:value-of select="$node/*[local-name(.)=$childname and
                                  namespace-uri(.)=$childns]"/>
  </xsl:when>

I hope this helps.

. . . . . . . . . . . . Ken


-- Upcoming XSLT/XSL-FO hands-on courses: Wellington, NZ 2009-01 Training tools: Comprehensive interactive XSLT/XPath 1.0/2.0 video G. Ken Holman mailto:gkholman@xxxxxxxxxxxxxxxxxxxx Crane Softwrights Ltd. http://www.CraneSoftwrights.com/s/ Male Cancer Awareness Nov'07 http://www.CraneSoftwrights.com/s/bc Legal business disclaimers: http://www.CraneSoftwrights.com/legal

Current Thread