Re: [xsl] Group by parameter tag

Subject: Re: [xsl] Group by parameter tag
From: David Carlisle <davidc@xxxxxxxxx>
Date: Wed, 25 Mar 2009 10:25:32 GMT
something like this, perhaps


<xsl:stylesheet version="2.0" 
		xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
		xmlns="http://bibtexml.sf.net/";
		xmlns:b="http://bibtexml.sf.net/";>
 
<xsl:strip-space elements="*"/>
<xsl:output indent="yes"/>

<xsl:param name="name" select="'note'"/>

<xsl:template match="*">
 <xsl:copy>
  <xsl:copy-of select="@*"/>
  <xsl:for-each-group select="node()" group-by="local-name()=$name">
   <xsl:choose>
    <xsl:when test="current-grouping-key()">
     <xsl:element name="{$name}">
      <xsl:for-each select="current-group()">
       <xsl:apply-templates/>
       <xsl:if test="position()!=last()"> and </xsl:if>
      </xsl:for-each>
     </xsl:element>
    </xsl:when>
    <xsl:otherwise>
     <xsl:apply-templates select="current-group()"/>
    </xsl:otherwise>
   </xsl:choose>
  </xsl:for-each-group>
 </xsl:copy>
</xsl:template>


</xsl:stylesheet>



which makes

<file xmlns="http://bibtexml.sf.net/";>
   <entry id="art">
      <article>
         <author>Isabel Men&#129;&#233;ndez and Luis Perez</author>
         <note>note1 and note2</note>
      </article>
   </entry>
   <entry id="conf">
      <conference>
         <author>Jhon Smith</author>
         <note>note5</note>
      </conference>
   </entry>
   <entry id="boo">
      <book>
         <title>The title</title>
         <note>note3 and note4</note>
      </book>
   </entry>
   <entry id="inb">
      <inbook>
         <pages>42</pages>
      </inbook>
   </entry>
</file>

________________________________________________________________________
The Numerical Algorithms Group Ltd is a company registered in England
and Wales with company number 1249803. The registered office is:
Wilkinson House, Jordan Hill Road, Oxford OX2 8DR, United Kingdom.

This e-mail has been scanned for all viruses by Star. The service is
powered by MessageLabs. 
________________________________________________________________________

Current Thread