Re: [xsl] match first occurrence for which a condition holds true

[David Carlisle <davidc@xxxxxxxxx>]

you might want to use format-number to avoid

  <MassPercent>40.349999999999994</MassPercent>


but:

<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform";>


<xsl:template match="*">
 <xsl:copy>
  <xsl:copy-of select="@*"/>
  <xsl:apply-templates/>
 </xsl:copy>
</xsl:template>

<xsl:template match="LeafExtName">
 <xsl:variable name="m" select="max(*/*/MassPercent)"/>
 <xsl:copy>
  <xsl:copy-of select="@*"/>
  <xsl:apply-templates >
   <xsl:with-param name="mp" 
select="(*/*/MassPercent[number(.)=$m])[1]" tunnel="yes"/>
   <xsl:with-param name="t" select="sum(*/*/MassPercent)" tunnel="yes"/>
  </xsl:apply-templates>
 </xsl:copy>
</xsl:template>

<xsl:template match="MassPercent">
 <xsl:param name="mp" tunnel="yes"/>
 <xsl:param name="t" tunnel="yes"/>
 <xsl:copy>
  <xsl:value-of select="if(. is $mp) then . + 100 - $t else ."/>
 </xsl:copy>
</xsl:template>

</xsl:stylesheet>

________________________________________________________________________
The Numerical Algorithms Group Ltd is a company registered in England
and Wales with company number 1249803. The registered office is:
Wilkinson House, Jordan Hill Road, Oxford OX2 8DR, United Kingdom.

This e-mail has been scanned for all viruses by Star. The service is
powered by MessageLabs. 
________________________________________________________________________