Re: [xsl] Removing unwanted namespaces

Subject: Re: [xsl] Removing unwanted namespaces
From: Markus Abt <abt@xxxxxxxx>
Date: Fri, 13 Jan 2012 17:10:08 +0100
Hi,

I wasn't aware of this requirement. Then indeed we need one more
template for the root element, but it shall copy only those namespaces
which don't belong to the suppressed elements or their descendants:

<xsl:template match="/*">
   <xsl:element name="{name(.)}" namespace="{namespace-uri(.)}">
      <xsl:copy-of select="//*[
         not(ancestor-or-self::*[
            local-name()='abcdHeader' or local-name()='Context'
         ])]/namespace::*[.=namespace-uri(..)]"/>
      <xsl:apply-templates select="@*|node()"/>
   </xsl:element>
</xsl:template>

Cheers,
Markus

Wendell Piez wrote:
> Hi again,
> 
> Yes, this will work, but I think Ram also said he wants all namespace 
> declarations at the top. Since this logic effectively strips all 
> namespace nodes except where they are needed, the declarations will only 
> appear at the point (or points, within the tree hierarchy) of first use.
> 
> (I also don't like using "*[local-name()='x']" tests but I'm unwilling 
> to say they're bad, exactly. It's just that there are usually more 
> graceful ways. :-)
> 
> Cheers,
> Wendell
> 
> On 1/11/2012 7:04 PM, Markus Abt wrote:
>> <?xml version="1.0"?>
>> <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"; version="1.0">
>>
>> <xsl:template match="@*|node()" priority="-1">
>>     <xsl:copy>
>>        <xsl:apply-templates select="@*|node()"/>
>>     </xsl:copy>
>> </xsl:template>
>>
>> <xsl:template match="*">
>>     <xsl:element name="{name(.)}" namespace="{namespace-uri(.)}">
>>        <xsl:apply-templates select="@*|node()"/>
>>     </xsl:element>
>> </xsl:template>
>>
>> <xsl:template match="*[local-name()='abcdHeader']"/>
>> <xsl:template match="*[local-name()='Context']"/>
>>
>> </xsl:stylesheet>

Current Thread