Re: [xsl] Split table row on paragraphs

On 30.10.2018 17:46, kevinbrianbird@xxxxxxxxx wrote:

I have tables with arbitrary columns and each cell can have an arbitrary number of paragraphs. I want to split rows on paragraphs, so each row only contains one element.

Simplified input:

<table>

<tr>

<td>

Para 1

</td>

<td>

Para 1

Para 2

Para 3

</td>

<td>

Para 1

Para 2

</td>

</tr>

</table>

Desired output:

<table>

<tr>

<td>

Para 1

</td>

<td>

Para 1

</td>

<td>

Para 1

</td>

</tr>

<tr>

<td>

</td>

<td>

Para 2

</td>

<td>

Para 2

</td>

</tr>

<tr>

<td>

</td>

<td>

Para 3

</td>

<td>

</td>

</tr>

</table>

I am after suggestions as to the best way of tackling such a problem.

Assuming at least XSLT 2 and that the "td" elements only "p" elements I think you can simply process each "tr" element 1 to max(td/count(p)) times with e.g.

  <xsl:template match="tr">
      <xsl:variable name="this-row" select="."/>
      <xsl:for-each select="1 to max(td/count(p))">
          <tr>
              <xsl:apply-templates select="$this-row/*">
                  <xsl:with-param name="pos" select="."/>
              </xsl:apply-templates>
          </tr>
      </xsl:for-each>
  </xsl:template>

  <xsl:template match="td">
      <xsl:param name="pos"/>
      <xsl:copy>
          <xsl:apply-templates select="p[$pos]"/>
      </xsl:copy>
  </xsl:template>

Online sample using XSLT 3 (but only for setting up the identity transformation with xsl:mode) is at https://xsltfiddle.liberty-development.net/6qVRKx7.

<- Previous	Index	Next ->
[xsl] Split table row on paragraphs, kevinbrianbird@xxxxx	Thread	Re: [xsl] Split table row on paragr, kevinbrianbird@xxxxx
[xsl] Split table row on paragraphs, kevinbrianbird@xxxxx	Date	Re: [xsl] Split table row on paragr, kevinbrianbird@xxxxx
	Month

<-prev [Thread] next->	<-prev [Date] next->
Month Index \| List Home