Re: [xsl] unfold one element to several elements according to its attribute

[Martin Honnen <Martin.Honnen@xxxxxx>]

mixhere wrote:
> Hello everyone,
> is it possible to do the translation? you can add other
> elements/attributes in the original xml if the info is not enough.
> thanks.
>
> Original:
> <product id="1" owner="a,b,c">
> <title owner="a,b">foo</title>
> <title owner="c">bar</title>
> </product>
>
> After translation:
> <product id="1" owner="a">
> <title>foo</title>
> </product>
> <product id="1" owner="b">
> <title>foo</title>
> </product>
> <product id="1" owner="c">
> <title>bar</title>
> </product>

Assuming there is a common root element then the following XSLT 2.0 
stylesheet does the transformation:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
  version="2.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="root">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="product">
    <xsl:variable name="p" select="."/>
    <xsl:for-each select="tokenize(@owner, ',')">
      <product id="{$p/@id}" owner="{.}">
        <title>
          <xsl:value-of select="$p/title[tokenize(@owner, ',') = 
current()]"/>
        </title>
      </product>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>


--

	Martin Honnen
	http://JavaScript.FAQTs.com/