Re: [xsl] Combining nodes

[David Carlisle <davidc@xxxxxxxxx>]

> I'm thinking I need to create 2 variables, one for the Fees nodes, one
> for the Product nodes, and then combine them somehow?  I guess I need to
> know how to create the variables 

you are making it sound far too complicated, you don't need any
variables at all.

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform";>

<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="Input">
 <xsl:apply-templates select="(Fees/Fee[not(IsPublicOfficial='true')],
			      Products/DealStructureProduct[not(IsInsurance='true')])
			      [position()&lt;4]"/>
</xsl:template>

<xsl:template match="Fee">
 <FieldValuePair name="label{position()}" value="{Code}"/>
 <FieldValuePair name="value{position()}" value="{Amount}"/>
</xsl:template>

<xsl:template match="DealStructureProduct">
 <FieldValuePair name="label{position()}" value="{Code}"/>
 <FieldValuePair name="value{position()}" value="{SellingPrice}"/>
</xsl:template>

</xsl:stylesheet>


produces:

$ saxon9 input.xml input.xsl 
<?xml version="1.0" encoding="UTF-8"?>
<FieldValuePair name="label1" value="inspection"/>
<FieldValuePair name="value1" value="4.00"/>
<FieldValuePair name="label2" value="vsc"/>
<FieldValuePair name="value2" value="210.00"/>
<FieldValuePair name="label3" value="ppm"/>
<FieldValuePair name="value3" value="250.00"/>

________________________________________________________________________
The Numerical Algorithms Group Ltd is a company registered in England
and Wales with company number 1249803. The registered office is:
Wilkinson House, Jordan Hill Road, Oxford OX2 8DR, United Kingdom.

This e-mail has been scanned for all viruses by Star. The service is
powered by MessageLabs. 
________________________________________________________________________