Re: [xsl] Merge 2 xmls : Loop through one xml and get elements from second xml

["Martin Honnen martin.honnen@xxxxxx" <xsl-list-service@xxxxxxxxxxxxxxxxxxxxxx>]

Am 01.09.2020 um 14:41 schrieb Prady Prady prady.chin@xxxxxxxxx:

> But I need to use only XSLT 1.0

Declare

<xsl:param name="doc2" select="document('Orders_Part2.xml')"/>

and a key

<xsl:key name="order" match="order" use="order_number"/>

then use

<xsl:template match="order">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
    <xsl:variable name="ordernumber" select="order_number"/>
    <xsl:for-each select="$doc2">
      <xsl:apply-templates select="key('order', $ordernumber)/amount"/>
    </xsl:for-each>
  </xsl:copy>
</xsl:template>

plus the identity transformation

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>



> > >     =================
> > >     Merge 2 xmls : Loop through one xml and get elements from second xml
> > >
> > >     I have 2 xmls(Orders_Part1.xml,Orders_Part2.xml). I have to build the
> > >     3rd xml ( Orders.xml) .