Re: [xsl] xsl:for-each-group help needed !

["Martin Honnen martin.honnen@xxxxxx" <xsl-list-service@xxxxxxxxxxxxxxxxxxxxxx>]

On 16.09.2020 23:19, Christophe Marchand cmarchand@xxxxxxxxxx wrote:
> Hello all !
>
> A slide is divided as blocks. Usually, there is one bloc per line, but
> sometimes, two or more blocks can be on one line, if their width sum is
> 100.
>
> My input has non-grouped blocks, and I want my input group blocks per line.
>
> Here is a sample input :
>
> <blocks>
>  B  <block id="i1">content</block>
>  B  <block id="i2" width="33">content</block>
>  B  <block id="i3" width="67">content</block>
>  B  <block id="i4" width="50">content</block>
>  B  <block id="i5" width="50">content</block>
>  B  <block id="i6" width="25">content</block>
>  B  <block id="i7" width="55">content</block>
>  B  <block id="i8" width="20">content</block>
>  B  <block id="i9">content</block>
> </blocks>
>
> Here is the expected output :
>
> <blocks>
>  B  <block id="i1">content</block>
>  B  <block type="composite">
>  B  B  <block id="i2" width="33">content</block>
>  B B B  <block id="i3" width="67">content</block>
>  B  </block>
>  B  <block type="composite">
>  B  B  <block id="i4" width="50">content</block>
>  B B B  <block id="i5" width="50">content</block>
>  B  </block>
>  B  <block type="composite">
>  B  B  <block id="i6" width="25">content</block>
>  B B B  <block id="i7" width="55">content</block>
>  B  B  <block id="i8" width="20">content</block>
>  B  </block>
>  B  <block id="i9">content</block>
> </blocks>
>
> I have no idea of which form of for-each-group I have to use...
>
> Is a solution with two-pass where I first calculate cumulated width with
> an accumulator, followed a group-end-with="@cumulative-width eq 100"
> could be a correct solution ?

You can use that accumulator in your group-ending-with, without two
passes I think, but I only could get it to work by wrapping it into an
outer group-adjacent="not(@width)"

  <xsl:accumulator name="width" as="xs:integer" initial-value="0">
    <xsl:accumulator-rule match="blocks" select="0"/>
    <xsl:accumulator-rule match="block[not(@width)]" select="0"/>
    <xsl:accumulator-rule match="block[@width]" select="if ($value eq
100) then xs:integer(@width) else + $value + xs:integer(@width)"/>
  </xsl:accumulator>

  <xsl:template match="blocks">
    <xsl:copy>
      <xsl:for-each-group select="block" group-adjacent="not(@width)">
        <xsl:choose>
          <xsl:when test="current-grouping-key()">
            <xsl:apply-templates select="current-group()"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:for-each-group select="current-group()"
group-ending-with="block[accumulator-before('width') eq 100]">
              <block>
                <xsl:apply-templates select="current-group()"/>
              </block>
            </xsl:for-each-group>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>