Hi,
You may want to check out the source code for Cheetah. It uses the 6 digit
code necessary. Please note that I wrote this code before I knew what I was doing
so the movit routine is missing since it is ugly. It is basically just a delay loop and then
a RESP0 and a RESP1. Here is an excerpt from the code:
drawit
lda #$03 ; set both players to 3 copies
sta NUSIZ0
sta NUSIZ1
lda #$01 ; set vertical delay on for both players
sta VDELP0
sta VDELP1
ldx #$6 ; move players 12 columns over
ldy #$0
jsr movit
lda #$f0 ; set player 0 to move left 1 pixel
sta HMP0
sta WSYNC
sta HMOVE ; move player 0
sec
lda SCANLINE ; adjust scanline count
sbc GRHEIGHT
sta SCANLINE
loop2
ldy GRHEIGHT
lda ($AA),y ; get player0 copy1 data
sta GRP0
sta WSYNC
lda ($AC),y ; get player1 copy1 data
sta GRP1
lda ($AE),y ; get player0 copy2 data
sta GRP0
lda ($B0),y ; get player1 copy2 data
sta $E9
lda ($B2),y ; get player0 copy3 data
tax
lda ($B4),y ; get player1 copy3 data
tay
lda $E9
sta GRP1
stx GRP0
sty GRP1
sta GRP0
dec GRHEIGHT
bpl loop2 ; loop until done
lda #$00 ; clear player graphics
sta GRP1
sta GRP0
rts
>Reply to your message of 3/11/97 7:54 AM
>Before I spend a week barking up the wrong tree, can someone reveal how
>2600 games display scores? (not playfield like Combat, I mean high-res
>like Missile Command, Millipede, Defender, Pac-man, etc.) I suspect its
>three copies of each player, rewriting GRP0 and GRP1 between display of
>each copy.. am I right? This would account for the six-digit limit on
>all 2600 games I've seen except Dark Cavern, which had three dummy zeroes
>anyway.
>
>If I'm right, is there any easy way to rip the font used in one of those
>games so I don't have to reinvent the wheel? (also, using the same
>typeface might lend an air of classic-game credibility to the program.)
>End of message
Your Name
Father Flanagan's Boys' Home
Your E-Mail address
Your phone and fax number (optional)
--
Archives available at http://www.biglist.com/lists/stella/archives/
E-mail UNSUBSCRIBE in the body to stella-request@xxxxxxxxxxx to be removed.
