At 15:11 29.12.98 -0600, you wrote:
> P.S. I have only one question that has bugged the heck out of me... How
>did they get the words "Cookie Monster Munch" or "Big Bird's Egg Catch" on
>screen? There is no flickering. I don't unndertand, save for the guess
>that they are not playfield graphics, and are probably player graphics.
They are playfield graphics. You only have to write the value for
the right half of the picture into each PF register after the left
half of the picture has be displayed but before the right half of
the picture would be displayed in every scanline.
The following routine will display a 40*24 pixel picture.
PF0-L, PF1-L, PF2-L, PF0-R, PF1-R and PF2-R are labels for the
graphics data. (24 lines each stored bottom up)
lda #%00000000 ;repeated playfield
sta CTRLPF
ldy #23 ;number of vertical pixels in text - 1
L1:ldx #7 ;number of scanlines per text-pixel - 1
L2:sta WSYNC
lda PF0-L,y
sta PF0
lda PF1-L,y
sta PF1
lda PF2-L,y
sta PF2
lda PF0-R,y
sta PF0 ;cycle 28 - PF0 has just finished
nop
nop
lda PF1-R,y
sta PF1 ;cycle 39 - PF1 has just finished
nop
nop
lda PF2-R,y
sta PF2 ;cycle 50 - PF2 has just finished
dex
bpl L2
dey
bpl L1
Ciao, Eckhard Stolberg
--
Archives (includes files) at http://www.biglist.com/lists/stella/archives/
Unsub & more at http://www.biglist.com/lists/stella/
