Re: [xsl] formatting problem

Subject: Re: [xsl] formatting problem
From: "Joerg Heinicke" <joerg.heinicke@xxxxxx>
Date: Wed, 20 Feb 2002 21:02:47 +0100
> I am trying to have whats between the tags to printout via XSL to HTML
> exactly as it is.  What keeps happening is that the white spaces get
deleted
> and it doesn't recognize the line feeds.  Any ideas what I'm doing wrong ?
> The XML snippet is below.
>
> Thank You for your help

Hello Gene,

I'm quite sure, that this isn't a XSL-problem, but normal HTML-behaviour.
Did you ever try to place more than one spaces in HTML?

Is this what you have? Many spaces and linebreaks, removed in HTML.

<xsl:template match="ARTICLE">
    <xsl:value-of select="."/>
</xsl:template>

Try the following (replacing spaces with non-breaking spaces and linebreaks
with <br/>):

<xsl:template match="ARTICLE">
    <xsl:call-template name="linebreaks">
        <xsl:with-param name="string" select="translate(., ' ', '&#160;')"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="linebreaks">
    <xsl:param name="string"/>
    <xsl:choose>
        <xsl:when test="contains($string, '&#10;')">
            <xsl:value-of select="substring-before($string, '&#10;')"/>
            <br/>
            <xsl:call-template name="linebreaks">
                <xsl:with-param name="string"
select="substring-after($string, '&#10;')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$string"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

This handles only linefeed, maybe you still need to handle carriage return.
we replaced &#13; with 'nothing', so you have to change the with-param in
the first template:

        <xsl:with-param name="string" select="translate(., ' &#13;',
'&#160;')"/>

This means: replace ' ' (space) with &#160; (non-breaking space) and &#13;
(carriage return) with nothing.

Does this help?

Regards,

Joerg


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list


Current Thread