RE: [xsl] Reference problem

[Jarno.Elovirta@xxxxxxxxx]

Hi,

> The problem is with idref attribute. How am i going to refer 
> to these newly
> created dataTypes nodes with their IDs ?it is possible or not ?
> Thanks a lot.

Something in the lines of

  <xsl:template match="/">
    <document>
      <dataTypes>
        <xsl:apply-templates select="document('')/*/x:dataTypes/dataType"/>
      </dataTypes>
      <xsl:apply-templates select="variables"/>
    </document>
  </xsl:template>
  <xsl:template match="var">
    <xsl:copy>
      <xsl:apply-templates select="@name"/>
      <xsl:for-each select="@type">
        <xsl:element name="{local-name()}">
          <xsl:attribute name="idref">
            <xsl:value-of select="document('')/*/x:dataTypes/dataType[@name = current()]/@id"/>
          </xsl:attribute>
        </xsl:element>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  <x:dataTypes>
    <dataType id="1" name="string"/>
    <dataType id="2" name="integer"/>
    <dataType id="3" name="float"/>
  </x:dataTypes>

Cheers,

Jarno - VNV Nation: Arclight

 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list