Re: [xsl] Transforming tabular information to hierarchical

["Andrew Welch" <andrew.j.welch@xxxxxxxxx>]

On 2/13/07, Simon Shutter <simon@xxxxxxxxxxx> wrote:
> If I have a tabular data set that defines parent-child relationships, is it
> possible to transform this into a hierarchical tree format using XSLT?

Here's a csv to XML converter I wrote the other day, feel free to
convert it to use tabs, or adjust your input to be comma delimited.


<xsl:stylesheet version="2.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
	xmlns:xs="http://www.w3.org/2001/XMLSchema";
	exclude-result-prefixes="xs">

<xsl:output indent="yes" encoding="US-ASCII"/>

<xsl:param name="pathToCSV" select="'file:///c:/temp/test.csv'"/>

<xsl:template name="main">
	<xsl:choose>
		<xsl:when test="unparsed-text-available($pathToCSV)">
			<xsl:variable name="csv" select="unparsed-text($pathToCSV)"/>
			<xsl:variable name="lines" select="tokenize($csv, '&#xa;')" as="xs:string+"/>
			<xsl:variable name="elemNames" select="tokenize($lines[1], ',')"
as="xs:string+"/>
			<root>
				<xsl:for-each select="$lines[position() > 1]">
					<row>
						<xsl:variable name="lineItems"
select="tokenize(normalize-space(.), ',')" as="xs:string+"/>
						<xsl:for-each select="$elemNames">
							<xsl:variable name="pos" select="position()"/>
							<xsl:element name="{normalize-space(.)}">
								<xsl:value-of select="$lineItems[$pos]"/>
							</xsl:element>
						</xsl:for-each>
					</row>
				</xsl:for-each>
			</root>
		</xsl:when>
		<xsl:otherwise>
			<xsl:text>Cannot locate : </xsl:text><xsl:value-of select="$pathToCSV"/>
		</xsl:otherwise>
	</xsl:choose>
</xsl:template>
</xsl:stylesheet>