Re: [xsl] only display if subnodes occur more than once

[David Carlisle <davidc@xxxxxxxxx>]

This is a grouping problem, so in xslt 1, S. Muench rescues you again...

<root>
         <sub_a>
                 <elem_1/>
                 <elem_2/>
                 <elem_3/>
         </sub_a>
         <sub_b>
                 <elem_1/>
                 <elem_2/>
                 <elem_2/>
                 <elem_2/>
                 <elem_3/>
         </sub_b>
         <sub_c>
                 <elem_1/>
                 <elem_2/>
                 <elem_3/>
         </sub_c>
</root>


<xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
>

<xsl:output indent="yes"/>

<xsl:key name="x" match="root/*/*"
use="concat(generate-id(..),':',name())"/>
<xsl:template match="root">
<root>
<xsl:for-each
select="*/*[generate-id()=generate-id(key('x',concat(generate-id(..),':',name()))[2])]">
<xsl:element name="{name(..)}">
<xsl:copy-of select="key('x',concat(generate-id(..),':',name()))"/>
</xsl:element>
</xsl:for-each>
</root>
</xsl:template>
</xsl:stylesheet>





$ saxon subnode.xml  subnode.xsl
<?xml version="1.0" encoding="utf-8"?>
<root>
   <sub_b>
      <elem_2/>
      <elem_2/>
      <elem_2/>
   </sub_b>
</root>

________________________________________________________________________
This e-mail has been scanned for all viruses by Star. The
service is powered by MessageLabs. For more information on a proactive
anti-virus service working around the clock, around the globe, visit:
http://www.star.net.uk
________________________________________________________________________